Вот что получилось на ночь глядя (не судите строго):
файл testConfigs.cmd лежит рядом с остальными cmd. Читает настройки из файла settings.txt (который лежит там же). Выводит список настроек на экран. Запускает gdpi с выбранным конфигом. По enter закрывает gdpi, останавливает windivert, снова выводит список настроек. И так по кругу.
файл testConfigs.cmd
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set blackList=
set /P blackList=Use only for sites from blacklist? (default=no):
if defined blackList (
set blackList=--blacklist ..\russia-blacklist.txt --blacklist ..\russia-youtube.txt)
set dnsRedir=
set /P dnsRedir=Use yandex dns? (default=no):
if defined dnsRedir (
set dnsRedir=--dns-addr 77.88.8.8 --dns-port 1253 --dnsv6-addr 2a02:6b8::feed:0ff --dnsv6-port 1253)
set settingsFile=settings.txt
set configsCount=0
for /F %%C in ('FIND /V /C "" ^<"%settingsFile%"') do (
set /A configsCount=%%C)
(for /L %%i in (1,1,%configsCount%) do set config.%%i=&set /P config.%%i=)<"%settingsFile%"
set configs=
for /L %%j in (1,1,%configsCount%) do (
set configs=!configs! config.%%j)
PUSHD "%~dp0"
set _arch=x86
IF "%PROCESSOR_ARCHITECTURE%"=="AMD64" (set _arch=x86_64)
IF DEFINED PROCESSOR_ARCHITEW6432 (set _arch=x86_64)
PUSHD "%_arch%"
:loop
taskkill /IM "goodbyedpi.exe" /F
sc stop "WinDivert"
cls
call :Choice config configs
start "goodbyeDPI" goodbyedpi.exe %config% %dnsRedir% %blackList%
@echo Press Enter to continue...
pause>nul
goto :loop
ENDLOCAL DISABLEDELAYEDEXPANSION
:Choice
SETLOCAL ENABLEDELAYEDEXPANSION
set "values=!%~2!"
set count=0
for %%i in (%values%) do (
set /A count +=1
@echo !count!: !%%i!
set value.!count!=!%%i!)
set configNum=1
set /p configNum=Enter config number (default=1):
set result=!value.%configNum%!
ENDLOCAL DISABLEDELAYEDEXPANSION & (
set "%~1=%result%")
exit /b
примерный файл settings.txt
-e2
-e2 --reverse-frag
-e2 --reverse-frag --ip-id 54321
-e2 --wrong-seq --reverse-frag
-e2 --auto-ttl --reverse-frag
-e2 --wrong-seq --set-ttl 2 --frag-by-sni
-e1 --reverse-frag -p
-1
-5 -e1 -p
-5 -e1 --fake-gen 5 --fake-from-hex 160301FFFF01FFFFFF0303594F5552204144564552544953454D454E542048455245202D202431302F6D6F000000000009000000050003000000
-5 --fake-resend 2 --fake-gen 12 --frag-by-sni -q
-6 --fake-gen 2
-9 -e1 --fake-gen 16 –fake-from-hex f1c48aca82bf0716fe28fc31c87e259b84a489946d5c819809a31471f3a26e4bfb09bcaa8a3fbdabae152e0f1db41f1c4952d480204fc26d2b25
-9 --fake-gen 5 --fake-from-hex 160301FFFF01FFFFFF0303594F5552204144564552544953454D454E542048455245202D202431302F6D6F000000000009000000050003000000
Пока так. Естественно, можно еще добавить увеличение --fake-gen, еще что-нибудь. Вдруг кому пригодится.